ivci:nuva_sparql_queries [International Vaccines Codes Initiative]

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
<svg xmlns="http://www.w3.org/2000/svg" xmlns:xlink="http://www.w3.org/1999/xlink" aria-hidden="true" focusable="false" width="1em" height="1em" preserveAspectRatio="xMidYMid meet" viewBox="0 0 24 24" class="iconify mr-1" data-icon="mdi:arrow-left" style="vertical-align: -0.125em; transform: rotate(360deg);"><path d="M20 11v2H8l5.5 5.5l-1.42 1.42L4.16 12l7.92-7.92L13.5 5.5L8 11h12z" fill="currentColor"></path></svg>====== NUVA SPARQL Queries ======
These can be run against the [[https://graph.ivci.org/sparql|SPARQL Query engine]]

<code>
# All vaccines against smallpox
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT ?vac ?vl WHERE { 
 ?dis rdfs:subClassOf nuva:Disease .
 ?dis rdfs:label "Smallpox-Monkeypox"@en .
 ?vac rdfs:subClassOf nuva:Vaccine .
    ?vac rdfs:label ?vl FILTER(lang(?vl)='en'||lang(?vl)=''). 
 ?vac nuvs:containsValence ?val . 
 ?val nuvs:prevents ?dis 
 }
</code>

<code>
# All Tdap only vaccines
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT ?vac ?vl WHERE {
    ?val1 skos:altLabel 'd'@en .
    ?val2 skos:altLabel 'T'@en .
    ?val3 skos:altLabel 'ap'@en .
    ?vac nuvs:containsValence ?val1 .
    ?vac nuvs:containsValence ?val2 .
    ?vac nuvs:containsValence ?val3 .
    ?vac rdfs:label ?vl FILTER(lang(?vl)='en'||lang(?vl)='')
    FILTER NOT EXISTS {
        ?vac nuvs:containsValence ?val .
        FILTER (?val NOT IN (?val1,?val2,?val3))
    }
 }
</code>

<code> 
# Convert from CIS to CNK
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT ?vac ?vl ?cnk WHERE { 
 ?vac skos:exactMatch nuva:CIS-65017887 .
 ?vac rdfs:label ?vl .
 ?vac skos:exactMatch ?cnk .
 ?cnk rdfs:subClassOf nuva:CNK .
 }
</code>

<code> 
# Vaccines codable as J07CA08
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT DISTINCT ?vac ?lvac WHERE { 
 ?vac rdfs:subClassOf nuva:Vaccine . 
 ?vac rdfs:label ?lvac FILTER (lang(?lvac)='fr'||lang(?lvac)=''). 
 ?rvac skos:exactMatch nuva:ATC-J07CA08 .
 FILTER NOT EXISTS { 
   ?rvac nuvs:containsValence ?rval . 
   FILTER NOT EXISTS {
   ?vac  nuvs:containsValence/rdfs:subClassOf* ?rval} 
   }  
  }
</code>

<code>  
# Seek parents
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT ?vac ?lvac WHERE { 
 ?rvac rdfs:label "BOOSTRIX" .
 ?vac rdfs:subClassOf nuva:Vaccine . 
 ?vac nuvs:isAbstract true .
 ?vac rdfs:label $lvac FILTER (lang(?lvac)='en') . 
 # Only vaccines having all valences of the reference vaccine
 FILTER NOT EXISTS { 
   # Search all valences of ?vac that are not parents of valences from ?rvac
   ?vac nuvs:containsValence ?val . 
   FILTER NOT EXISTS {
     # Empty if ?vac is not a parent of any ?rvac
     ?rvac nuvs:containsValence/rdfs:subClassOf* ?val} 
     } 
   }
</code>

<code>
# Seek ATC Code
# Similar to Seek parents
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX nuva: <http://ivci.org/NUVA#> 
PREFIX nuvs: <http://ivci.org/NUVA/nuvs#>
SELECT ?vac ?lvac ?atc WHERE { 
 ?rvac rdfs:label "BOOSTRIX" .
 ?vac rdfs:subClassOf nuva:Vaccine . 
 ?vac nuvs:isAbstract true .
 ?vac skos:exactMatch ?code .
 ?code rdfs:subClassOf nuva:ATC .
 ?code skos:notation ?atc .
 ?vac rdfs:label $lvac FILTER (lang(?lvac)='en') . 
 FILTER NOT EXISTS { 
   ?vac nuvs:containsValence ?val . 
   FILTER NOT EXISTS {
     ?rvac nuvs:containsValence/rdfs:subClassOf* ?val} 
     } 
   }
</code>